You need to add the method: transferCam to the Class. We will not talk about it here. Only use it.:

transferCam: object

| trans |	
object ifNotNil:[
 self activeCamera parent = object 
  ifTrue:[
   trans := (self activeCamera) globalTransform.
   (self activeCamera) transferTo: (object parent).
   (self activeCamera) localTransform: trans.]
  ifFalse:[
   trans := object globalTransform orthoNormInverse composeWith: (self activeCamera) globalTransform.
   self activeCamera transferTo: object.
   self activeCamera localTransform: trans.
   self activeCamera translationX: 0 y: 0 z:16 .
   self activeCamera rotationAroundY: 0.
  ]
]

We will use here also a TimeStep loop. We will have two methods:

wantsSteps

^true.

And the TimeStep:

stepAt: currentTime

| dur |
super step.
space ifNil: [^self].

world connect.
space connect.
					
dur := ((currentTime asFloat) - (prevTime asFloat)) / 1000.
prevTime := currentTime.
	
	 
sceneObjects do:[:id|
  | each body |
	each := id at:1. 
	body := id at:2.
	each isStepping not ifTrue:[
	 each localTransform: body transform transposed.
	]
	ifFalse:[ 
	 body linearVel:  each globalPosition - (body position) * 10.	
	 body position: each globalPosition.
	 body quaternion: (each quaternion)
	]
].
space collideDo: [:geom1 :geom2 |  
 contacts	
   addContact: geom1
   with: geom2
   bounce: 0.03
   bounceVel: 0.2
   softCFM: 0.000000001.].
   world quickStep: dur.  

contacts empty.

CODE COMMENTS

• 1 - In the TimeStep we capture the collision of 2 "geoms" and, at this moment, is created a "contact" - really a point of "conflict". We have some definitions for this "conflict", like velocity etc. After this, the "contact" ends - is empty.

And we have an important method that will define how the "legoic" moves in the space. We are using for him the "DOOM paradigma" and you will use the "arrow keys" to control their movements. The method is:

keyStroke: anEvent
	
| kv kc bb |
kc := anEvent keyCharacter asLowercase.
kv := anEvent keyValue.

bb:= legMODE .
  
"The codes for arrow keys are: 28, 29, 30, 31" 
kv = 30 ifTrue:[ 
 bb   translation: bb translation+( bb localTransform column3*-0.5). 
 bb body position: bb globalPosition.  
]. 
kv = 31 ifTrue:[ 
 bb   translation: bb translation+( bb localTransform column3*0.5).   	 
 bb body position:bb globalPosition. 
]. 
kv = 28 ifTrue:[ 
 bb addRotationAroundY:2.
 bb body quaternion: bb quaternion.
].    
kv = 29 ifTrue:[ 
 bb addRotationAroundY:-2.
 bb body quaternion: bb quaternion.
].

"To create 3 balls, press P"
kc = $p ifTrue:[ 
self addBall2.
self addBall2.
self addBall2.
].

(#(28 29 30 31) includes: kv) ifTrue: [^self]. 

"To change the camera legoic/avatar use Esc key"	
kv = 27 ifTrue:[
^self transferCam:bb].
	
super keyStroke: anEvent.

CODE COMMENTS

• 1- We are using here the arrow keys for administration of the movements. They have key-codes.
• 2 - "bb" or "legMODE" is the object of the Class LegoicMODE defined in the initializeDefaultSpace method.
• 3 - We need to move also the "body" of the piece. The same movement/position of the piece.
• 4 - "quartenion" is a funny name for the matrix where we have the rotation of the piece.
• 5 - The "legoic" will kick balls. This balls will be created at "execution time" by the user . Each time the user presses the "P" key, 3 balls will fall from the sky to the floor (using the gravity effect). You can create many balls...

For the creation of balls the method (also from the ODECo demo) is:

addBall2 

| body geom textures  ball2 |
textures := #('BasketballColor.jpg' 'TennisBall.jpg' 'Softball.jpg' 'BeachBall.jpg' ).
txtr := TTexture new initializeWithFileName: (textures at: rnd next * textures size truncated + 1).
txtr scale: 14.
ball2 := TSphereODE new.
ball2 translationX: 0 y: 15 z: 0.
ball2 radius: 1.
ball2 texture: txtr.
ball2 segments: 30.
cworld addChild: ball2.
world add: (body := ODEBody new).
body position: ball2 globalPosition.
body massSphere: 1.
space add: (geom := ODESphere new radius: ball2 radius).
geom body: body.
ball2 body: body.
sceneObjects at: body id put: {ball2. body. geom}

CODE COMMENTS

• 1 -The code uses a randomic number to choose the texture of each ball created.
• 2 - The Class TSphereODE creates an sphere by code, not using an .ASE file.
• 3 - Like for the other piece (the "legoic"), we need to create a "body" and a "geom". And to define a mass - here was used 1 for the mass - they are like balloons...
• 4 - We include the ball in the Collection "sceneObjects" like we did with the "legoic". All is similar.

Finally we need to create a Cube (required). The method is:

addCube
	
| body geom cube1  |
txtr := TTexture new initializeWithFileName: 'checker.bmp'.
txtr scale: 13.
cube1 := TCubeODE new.
cube1 translationX: 20 y: 3 z: 10.
cube1 extent: 4 @ 4 @ 4.
cube1 texture: txtr.
cworld addChild: cube1.
world add: (body := ODEBody new).
body position: cube1 globalPosition.
body massSphere: 5. 
space add: (geom := ODEBox new extent: cube1 extent).
geom body: body.
cube1 body: body.
sceneObjects at: body id put: {cube1. body. geom}.

CODE COMMENTS

• 1 - Here the creation of a cube uses code, not an .ASE files. All is very similar the previous method. This cube will not appear in the space.

To run our exercice you need an "script for Workspace". We are not using the Private area - it's only an exercice - but it would be the adequate area.:

oD:= MyODE new. 
win2D:=   SystemWindow new.
lf:= LayoutFrame new.
lf leftFraction:0.
lf rightFraction:1.
lf topFraction:0.
lf bottomFraction:1.
win2D setLabel: 'ODE'.
win2D addMorph: oD fullFrame:lf.
win2D openInWorldExtent: 500@500. 
oD requestInitialSpace.

Look some figures of our exercice:

PREVIOUS  LESSON       NEXT  LESSON              
T. CONTENTS           HOMEPAGE